!7

p {
  L<Pair<WebNode>> nodePairs = chatHistory_peepHole_nodePairs();
  print("Have " + n(nodePairs, "node pair"));
  
  // Analysis
  
  new MultiMap<S, WebNode> index; // left text to right node
  
  for (Pair<WebNode> p : nodePairs) {
    L<S> texts = web_texts(p.a);
    for (S text : texts)
      index.setPut(text, p.b);
  }
  print("Index size: " + index.keysSize() + " / " + index.size());
  
  MultiSet<S> ms = multiMapAsMultiSet(index);
  
  new L<Web> outWebs;
  
  for (S key : ms.highestFirst()) {
    L<WebNode> nodes = index.get(key);
    if (l(nodes) < 2) continue;
    
    print(l(nodes) + " - testing key " + key);
    L<S> common = web_commonTexts(nodes);
    LL<S> l = map web_texts(nodes);
    if (nempty(common)) {
      print("  Always: " + common);
      outWebs.add(webFromTriples2(key, ll("then", "checked " + n(nodes, "time")), common));
      for (L x : l ) x.removeAll(common);
    }
    //Pair<S, Int> p = web_mostCommonTextWithCount(nodes);
    Pair<S, Int> p = mostCommonWithCount(l);
    if (p != null && p.b > 1) {
      int percent = ratioToIntPercent(p.b, l(nodes));
      print("  Often (" + percent + "%): " + p.a + " (" + p.b + ")");
      outWebs.add(webFromTriples2(key, ll("then maybe", "(" + p.b + "/" + n(nodes, "time") + ")"), p.a));
    }
  }
  
  print("Made " + n(outWebs, "out web"));
  //showWeb(last(outWebs));
  if (isMain())
    showWeb(firstWebContaining(outWebs, "then maybe"));
  
  saveGZStructure("peephole-webs.structure.gz", outWebs);
}

Began life as a copy of #1010968