!7

sclass ClipboardContents > DynSCP {
  S imageMD5, text;

  JComponent visualize() {
    ret awtEvery(super.visualize(), 3000, 0, r actualUpdate);
  }

  void actualUpdate {
    temp enter();
    
    Transferable transferable = Toolkit.getDefaultToolkit().getSystemClipboard().getContents(null);
    S mimeTypes = joinWithNewLine(mimeTypes(transferable));

    L<File> f = getFilesFromClipboard();
    if (nempty(f)) {
      S s = lines(map f2s(f));
      if (eq(s, getText(componentOfType(JTextArea, getComponent())))) ret;
      setModuleName("Clipboard: " + n2(f, "file"));
      setComponent(typeWriterTextArea(s));
      ret;
    }

    BufferedImage img = getImageFromClipboard();
    if (img != null) {
      S md5 = md5OfRGBImage(new RGBImage(img));
      if (neq(md5, imageMD5)) {
        setFields(imageMD5 := md5, text := null);
        setComponent(scrollableImageSurface(img));
        setModuleName("Clipboard: " + img.getWidth() + "*" + img.getHeight() + " px image");
      }
      ret;
    }
    
    setField(imageMD5 := null);
    S s = getTextFromClipboard();
    if (s != null) {
      if (neq(text, s)) {
        setField(text := s);
        setComponent(typeWriterTextArea(mimeTypes + "\n\n" + s));
        setModuleName("Clipboard: " + quote(escapeNewLines(shorten(s, 256))));
      }
      ret;
    }
    
    setField(text := null);
    
    // empty clipboard or unknown contents
    setComponent(jpanel());
  
    setModuleName(transferable != null
      ? "Unknown clipboard contents (" + mimeTypes + ")"
      : "Empty clipboard");
  }
}