!7

sS chatBotID = #1026221;

!include once #1026287 // Multi-Comm Concepts

cmodule MultiComm {
  transient ConceptTable<Customer> ct;
  
  start {
    dbIndexing(Customer, 'cookie, Customer, 'active, Message, 'customer);
    dm_vmBus_onMessage_q chatBot_userPolling(voidfunc(O mc, virtual Conversation conv) {
      Customer c = customerFromConv(mc, conv);
      if (c == null) ret;
    });
    
    dm_vmBus_onMessage_q chatBot_messageAdded(voidfunc(O mc, virtual Conversation conv, virtual Msg msg) {
      Customer c = customerFromConv(mc, conv);
      if (c == null) ret;
      S text = getString text(msg);
      bool fromUser = getBool fromUser(msg);
      if (fromUser)
        cnew(IncomingMessage, customer := c, +text, unread := true);
      else
        cnew(OutgoingMessage, customer := c, +text);
    });
    
    dm_registerAs_direct iptvMultiComm();
  }
  
  visualize {
    ct = new ConceptTable(Customer);
    ct.filter = c -> c.active();
    IF1<Customer, Map> renderer = defaultConceptRendererForTable(Customer);
    ct.renderer = c -> {
      Map map = renderer.get(c);
      map.remove("lastPing");
      transformValueInPlace str(map, "botConversationID");
      map.put("Last activity", iround(toSeconds(elapsedMS_timestamp(c.lastPing))));
      Message msg = c.lastMessage();
      map.put("Last message", msg == null ? "" : msg.text);
      ret map;
    };
    awtEvery(ct.getTable(), 5.0, r { ct.update() });

    ret jhsplit(
      jCenteredSection("Active Customers", ct.getTable()),
      jCenteredSection("Messages", makeConceptsTable(Message)));
  }

  Customer customerFromConv(O mc, virtual Conversation conv) {
    S cookie = getString cookie(conv);
    if (empty(cookie)) null;
    Customer c = uniq(Customer, +cookie);
    cset(c, ip := getString ip(conv));
    cset(c, lastPing := now(), botConversationID := 
      BotConversationID(programID(mc), getLong id(conv));
    ret c;
  }
  
  // API
  
  L<Customer> activeCustomers() {
    ret cloneList(conceptsWhere Customer(active := true));
  }
}