!7

concept Rule {
  S globalID = aGlobalIDUnlessLoading();
  S text;
  S comments;
}

// Bug when making cmodule
module Rules > DynCRUD<Rule> {
  enhanceFrame { internalFrameIcon(f, gazelle_frameIcon()); }
  
  start {
    dbIndexing(Rule, 'globalID);
    
    crud.multiLineFields = litset('text, 'comments);
    crud.dontDuplicateFields = litset('globalID);
    crud.renderer = func(Rule r) -> Map { litorderedmap("Rule ID" := r.globalID, text := joinWithSpace(tlft(r.text)), comments := escapeNewLines(r.comments)) };
    onConceptsChange(r { vmBus_sendMessage('gazelleRulesChanged, this) });
  }
  
  // API
  
  Pair<S, Bool> addRule(S when, S then) {
    ret addRule(when + "\n=> " + then);
  }
  
  Pair<S, Bool> addRule(S text) {
    ret addRuleWithComment(text, null);
  }
  
  Pair<S, Bool> addRuleWithComment(S text, S comment) {
    Pair<Rule, Bool> p = uniq2_sync(Rule,
      text := rtrim(text),
      comments := nullIfEmpty(rtrim(comment)));
    if (p.b) vmBus_sendMessage('gazelleRuleCreated, this, p.a);
    ret pair(p.a.globalID, p.b);
  }
  
  PairS textAndCommentForRule(S ruleID) {
    Rule r = conceptWhere Rule(globalID := ruleID);
    ret r == null ? null : pair(r.text, r.comments);
  }
}