!7

sclass Process {
  S processID, name, commandLine;
  long residentSize;
  double cpuUsage; // percent per core
  
  static S _fieldOrder = "processID name commandLine residentSize cpuUsage";
}

module ProcessList > DynObjectTable<Process> {
  bool showTiming;
  
  S switchableFields() { ret 'showTiming; }
  
  start {
    dontPersist();
    itemToMap = func(Process p) -> Map { humanizeKeys(
      applyFunctionToMapValue('cpuUsage, f iround_spacePercentSign,
      applyFunctionToMapValue('residentSize, f str_toM,
        objectToMap_honorFieldOrder(p)))) };
    actualUpdate(); // to make sort keys work
    doEvery(5.0, r actualUpdate);
  }
  
  afterVisualize {
    addRowSorter_desc(table, 3);
    rowSorter_setComparators(table, 4, alphaNumComparator(), 2, alphaNumComparator(), 3, alphaNumComparator(), );
    table.getRowSorter().sort();
    tablePopupMenuItem(table(), "Kill!", rThread { killProcess(selected().processID) });
  }
  
  void actualUpdate enter {
    L<OSProcess> list = timedIf(showTiming, func -> L<OSProcess> { oshi_listProcesses_withoutOpenFiles() });
    setData(map(list, func(OSProcess p) -> Process {
      nu(Process,
        processID := str(p.getProcessID()),
        name := p.getName(),
        commandLine := p.getCommandLine(),
        residentSize := p.getResidentSetSize(),
        cpuUsage := oshi_calcProcessCPUUsage_v2(p))
    }));
  }
}