sclass ai_Reconstructed {
  WeightedProduction production;
  AI_BottomUpParser1.Word a, b; // b may be null if it's a subclassing
  
  *(WeightedProduction *production, AI_BottomUpParser1.Word *a, AI_BottomUpParser1.Word *b) {}
  *(WeightedProduction *production, AI_BottomUpParser1.Word *a) {}
  
  toString { ret sfu(production) + " - " + a.text() + " + " + b.text(); }
}

static L<ai_Reconstructed> ai_buParser1_reconstructedProductions(AI_BottomUpParser1 parser, L<WeightedProduction> productions, AI_BottomUpParser1.Word group, S category) {
  L<ai_Reconstructed> l = new L;
  if (group == null || !group.isGroup()) ret l;
  
  for (WeightedProduction prod : productions)
    if (eq(category, prod.c)) {
      if (prod.b == null)
        continue with l.add(ai_Reconstructed(prod, group));
        
      for (L<AI_BottomUpParser1.Word> parts : group.constituents) {
        if (l(parts) != 2) continue; // shouldn't happen
        AI_BottomUpParser1.Word partA = first(parts), partB = second(parts);
        if (!contains(partA.classes, prod.a)) continue;
        if (!contains(partB.classes, prod.b)) continue;
        l.add(ai_Reconstructed(prod, partA, partB));
        //print("  Found grouping: " + partA.text + " + " + partB.text);
      }
    }

  ret l;
}